NISAN (ABIB) 14 CALCULATOR

HERE IS A SIMPLE COMMAND LINE PROGRAM TO DO THE SAME THING
----------------------------------------------------------
Author: Lucien LeSage
Email: lucienlesage@cox.net

MAIN PROGRAM CODE
-----------------
Program Nisan14CommandLine;
uses sysutils;

Const
  MonthAr: Array[1..12] of String =
    ('January','February','March','April','May','June',
     'July','August','September','October','November','December');

Type
  MyDateRecord = Record
    Year,Month,Day:Integer
   end;

var
  JewishYear,JulianYear,JDN:LongInt;
  Nisan14Date,Gregorian:MyDateRecord;
  BCAD:String; // BC or AD string

Function GetNisan14Date(JYear:LongInt):MyDateRecord; // Jewish Year Returns Julian Date
// Jewish Year 3761 = Julian Year 1
// Jewish Year 3760 = Julian Year -1 (1 BC)
// Jewish Year 1 = Julian Year -3760 (3760 BC)
// This routine developed from Gauss' Formula
var
  Year,a,b,c,Month,Day:LongInt;
  M,Temp:Real;
begin
  Year:=JYear;
  a:=((12*Year)+17) mod 19;
  b:=Year mod 4;
  M:=32+4343/98496+(1+272953/492480)*a+b/4-(313/98496)*Year;
  Month:=3; Day:=Trunc(M);
  Temp:=((3*Year)+(5*b)+Int(M)+5);
  c:=Trunc(Temp) mod 7;
  if ((c=2) or (c=4) or (c=6)) then
    Begin
      Month:=3;
      Day:=Trunc(M)+1;// March M+1
    End else
      if (c=1) and (a>6) and (Frac(M)>=1367/2160) then
        begin
          Month:=3;
          Day:=Trunc(M)+2;// March M+2
        end else
          if ((c=0) and (a>11) and (Frac(M)>=23269/25920)) then
          begin
            Month:=3;
            Day:=Trunc(M)+1;// March M+1
          end;
  Dec(Day); // Set to Nisan 14 - Gauss' formula was for Nisan 15
  If Day>31 then
    begin
      Inc(Month);
      Dec(Day,31);
    end;
  GetNisan14Date.Year:=Year-3760; // Julian Year
  GetNisan14Date.Month:=Month;
  GetNisan14Date.Day:=Day;
end;

Function GregDATE(JD:Real):MyDateRecord;
  // Returns Gregorian date from Julian Day Number
  // ChatGPT gave me this routine in Pascal code
var
  JDN, year, month, day, century, a, b, c, d, e: LongInt;
  begin
    JDN:=Trunc(JD);
    // Calculate auxiliary variables
    a := JDN + 32044;
    b := (4 * a + 3) div 146097;
    c := a - (146097 * b) div 4;
    // Calculate the centuries
    century := (4 * c + 3) div 1461;
    // Calculate the year within the century
    d := c - (1461 * century) div 4;
    e := (5 * d + 2) div 153;
    // Calculate the month
    month := e + 3 - 12 * (e div 10);
    // Calculate the day
    day := d - (153 * e + 2) div 5 + 1;
    // Calculate the year
    year := 100 * b + century - 4800; // Adjust for BC dates
    // Return the result
    // if year <= 0 then BC else AD
    GregDATE.YEAR:=Year;
    GregDATE.MONTH:=Month;
    GregDATE.DAY:=Day;
  end;

Function DayOfWeekStr(JDN:LongInt):String;// Julian Day Number needs to be an Integer
// Returns day of the week as a Name string, such as Monday, Tuesday, etc.
// 0=Monday, 1=Tuesday, ..., 6=Sunday
// ChatGPT suggested this simple one line formula if JDN is known
const
  JDNDowAr: Array[0..6] of String =
    ('Monday','Tuesday','Wednesday','Thursday','Friday','Saturday','Sunday');
var
  i:Integer;
begin
   i:=JDN mod 7;// Divide by 7 and use remainder as pointer into Day array
   DayOfWeekStr:=JDNDowAr[i];
end;

Function CalculateJulianDayNumber(MyDate:MyDateRecord):LongInt;
// Calculate Julian Day Number (JDN) from Julian Date
// Developed this routine myself
var
  JulianYear: LongInt;
  JulianDay: Real;
begin
  // Julian Day number starts on January 1, 4713 BC
  JulianYear:=MyDate.Year+4712;
  JulianDay:=JulianYear*365.25; // Number of days in a year
  If (((JulianYear) mod 4)=0) then JulianDay:=JulianDay+31+29-1 else
    JulianDay:=JulianDay+31+28; // Gets day to March 1
  // Previous if statement has same results for true and false and could be removed
  If MyDate.Month=4 then JulianDay:=JulianDay+31; // Gets to April 1 as March has 31 days
  // Nisan 14 will always be in March or April
  JulianDay:=JulianDay+MyDate.Day; // Gets to day in month
  CalculateJulianDayNumber:=Trunc(JulianDay); // Make an integer and discard part less than 1
end;

begin // Program begins here
  Writeln('Enter Julian Year to determine Nisan 14 date');
    // 0 or -1 is BC 1, for any BC date use minus in front of number
  Readln(JulianYear);
  If JulianYear<0 then Inc(JulianYear); // Make -1 equal value=0 or to 1 BC
    // Program treats 0 as 1 BC and -1 as 2 BC so zero is significant in calculation
  JewishYear:=JulianYear+3760; //Julian Year is AD but BC is entered as negative
    // Jewish Year 3761 = Julian Year 1 (AD)
    // Jewish Year 3760 = Julian Year -1 (1 BC)
    // Jewish Year 1 = Julian Year -3760 (3760 BC)
  Nisan14Date:=GetNisan14Date(JewishYear); // Julian Date: Uses Gauss' formula to calculate
  JDN:=CalculateJulianDayNumber(Nisan14Date); // JDN is day number since Jan 1, 4713 BC
  Gregorian:=GregDate(JDN);
  if Nisan14Date.Year<1 then // Make negative years display as BC positive number
     begin // BC
       Dec(Nisan14Date.Year);
       BCAD:='BC';
       Nisan14Date.Year:=Abs(Nisan14Date.Year); // Change negative number to positive BC
       Dec(Gregorian.Year);
       Gregorian.Year:=Abs(Gregorian.Year); // Change negative number to positive BC
     end else BCAD:='AD'; // AD
  // Display output here
  Writeln('Nisan (Abib) 14 for Jewish Year = '+IntToStr(JewishYear)+
    Chr(13)+Chr(10)+ // Carriage Return, Line Feed
    'Julian Date = '+MonthAr[Nisan14Date.Month]+' '+
    IntToStr(Nisan14Date.Day)+', '+
    IntToStr(Nisan14Date.Year)+' '+BCAD+
    Chr(13)+Chr(10)+ // Carriage Return, Line Feed
    'Day of the week = '+DayOfWeekStr(JDN)+
    Chr(13)+Chr(10)+ // Carriage Return, Line Feed
    'Gregorian Date = '+MonthAr[Gregorian.Month]+' '+
    IntToStr(Gregorian.Day)+', '+
    IntToStr(Gregorian.Year)+' '+BCAD);
  Writeln('Julian Day = '+IntToStr(JDN));
  writeln;
end.